Observing ¹²CO(2-1), ¹³CO(2-1), and C¹⁸O(2-1) Simultaneously

Hiroshige Yoshida
Caltech Submillimeter Observatory

With the wideband 230 GHz receiver (Frank Rice's receiver) and FFTS1 in the wideband mode or FFTS2, ¹²CO(2-1), ¹³CO(2-1), and C¹⁸O(2-1) can be observed simultaneously. The following UIP commands

UIP> VERIFY 12CO2-1U /LINE
12CO2-1U 230.538000 GHz USB
UIP> LO 12CO2-1U /RECEIVER RX230X /IF 5.28
UIP> SPECTROMETER /FFTS1W -0.72

nominally set up the receiver for this type of observations. You will be observing a ¹²CO line, with ¹³CO and C¹⁸O lines coming from the lower sideband. ¹³CO and C¹⁸O lines are 838 MHz apart. You do not have a choice but to place a ¹²CO line in between the two for the FFTS1. The above IF offsets are chosen so that ¹²CO falls right in the middle of two. The following CLASS procedure (swap_sidebands.class) can be used to process each scan to swap sidebands and shift the velocity scale for either ¹³CO or C¹⁸O:

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!! Copyright 2011 California Institute of Technology
!!!
!!! swap_sidebands.class
!!! 
!!! 2011-05-16 version 1.0 Initial release
!!! 2011-06-03 version 1.1 Copyright notice
!!!
!!! @swap_sidebands [ new_restf(MHz) ]
!!!
!!! Swaps signal and image sidebands.  Optionally moves reference channel and
!!! frequency.
!!!
!!! Use case: You have observed 12CO, 13CO, and C18O lines simultaneously with
!!! wideband receiver and spectrometer by doppler-tracking the 12CO frequency.
!!! The spectrometer was centered at the 12CO frequency in the signal sideband.
!!! Now you want scans *centered* at 13CO (or C18O) that was in the image
!!! sideband.
!!!
!!! file in ...
!!! file out ...
!!! find ...
!!! set variable spectro write
!!! set variable calibration write
!!! for i 1 to found
!!! get next
!!! @swap_sidebands 220398.6765
!!! write
!!! next
!!!
!!! C18O (J=2-1) 219560.3568 MHz
!!! 13CO (J=2-1) 220398.6765 MHz
!!! 12CO (J=2-1) 230538.0000 MHz

sic\let clight = 2.99792458e5 /new double ! Speed of light (km/s)

sic\let new_restf = image /new double
sic\let new_image = restf /new double
sic\let new_rchan = rchan /new real
sic\let new_fres = -fres /new real ! No change (topocentric!!!)
sic\let new_vres = -vres /new real

sic\if ("&1 ".ne." ") then
       sic\let new_restf = &1
sic\end if

sic\let new_image = (restf+image)-new_restf
sic\let new_rchan = rchan+(new_restf-image)*(1+doppler)/new_fres
sic\let new_vres = -clight*new_fres/((1+doppler)*new_restf)

sic\let restf = new_restf
sic\let image = new_image
sic\let rchan = new_rchan
sic\let fres = new_fres
sic\let vres = new_vres

sic\define real r4

sic\let r4 = tatms
sic\let tatms = tatmi
sic\let tatmi = r4

sic\let r4 = taus
sic\let taus = taui
sic\let taui = r4

The following similar CLASS procedure (shift_reference.class) shifts the velocity scale in the signal sideband, between ¹³CO and C¹⁸O after the sideband swap above, for example:

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!! Copyright 2011 California Institute of Technology
!!!
!!! shift_reference.class
!!!
!!! 2011-05-16 version 1.0 Initial release
!!! 2011-06-03 version 1.1 Copyright notice; use case; no write if no argument
!!!
!!! @shift_reference [ new_restf(MHz) ]
!!!
!!! Shifts reference channel and frequency.
!!!
!!! Use case: You have observed two or more lines simultaneously by doppler-
!!! tracking one of them.  The spectrometer was *centered* at the same line.
!!! Now you want scans *centered* at one of other lines in the signal sideband.
!!! To *center* at one of lines in the image sideband, use the procedure
!!! swap_sideband.class.
!!!
!!! file in ...
!!! file out ...
!!! find ...
!!! set variable spectro write
!!! for i 1 to found
!!! get next
!!! @shift_reference 220398.6765
!!! write
!!! next
!!!
!!! C18O (J=2-1) 219560.3568 MHz
!!! 13CO (J=2-1) 220398.6765 MHz
!!! 12CO (J=2-1) 230538.0000 MHz

sic\let clight = 2.99792458e5 /new double ! Speed of light (km/s)

sic\let new_restf = restf /new double
sic\let new_image = image /new double
sic\let new_rchan = rchan /new real
sic\let new_fres = fres /new real ! No change (topocentric!!!)
sic\let new_vres = vres /new real

sic\if ("&1 ".ne." ") then
       sic\let new_restf = &1
       sic\let new_image = (restf+image)-new_restf
       sic\let new_rchan = rchan+(new_restf-restf)*(1+doppler)/new_fres
       sic\let new_vres = -clight*new_fres/((1+doppler)*new_restf)

       sic\let restf = new_restf
       sic\let image = new_image
       sic\let rchan = new_rchan
       sic\let fres = new_fres
       sic\let vres = new_vres
sic\end if

---

File translated from T_EX by T_TH, version 4.03.
On 25 May 2012, 09:34.